Albatross Tutorial

Read the IDL Documentation

[ Introduction ] [ Albatross Display ] [ Using the Structure ] [ Using the Array ]
[ Tips and Tricks ]

Introduction

This is a tutorial to explain how to use the Albatross software. The tutorial describes how to use the graphical software to browse the data, and also how to use the data returned by the software for additional analysis.

NOTE: Each time an IDL command is shown in this tutorial, you can click on the IDL to get an image of what the command produces.

Albatross Display

Albatross allows you to view parts of the Mariner Mars 1971 UVS footprint reflectance database in many different ways, using many different backrounds for the spectra.

First, you must pick what you want to look at in the data set. This choice should either be a geographic region on the surface of Mars (picking an entire hemisphere is a valid choice), or a region of time from the dataset (you must know the DAS timestamps).

To view a region (in this example: Lyot Crater at lat,lon = 51,330)
IDL> albatross, location=[51,330], /no_motion, /mapping_only
  • location centers the map at any [lat,lon] pair.
  • no_motion limits the footprints to when the instrument platform was stationary.
  • mapping_only keyword limits the footprints to the Science Team Mapping Orbits.
Move the mouse around the image, and the footprint nearest the mouse has its spectra plotted. Some information about the footprint is also displayed in the plot and in a dialog box.
  • Press q to Quit.
  • Press b to Blink the nearest (active) footprint.
  • Press p to Pause/unPause. This will stop Albatross from interacting with the mouse, so you can plot in another window, etc.
  • Press r to view footrpint Ratios. The active footprint (when you press r) is set to the denominator. As you move the mouse, the nearest footrprint is set to the numerator. To switch from Ratio back to Reflectance, press r again.
  • Press t to see the TV image taken at the nearest DAS time.
  • Press L to List all TV images in the image.
After moving the mouse around you discover that orbit (REV) 182 is of interest... You want to re-display the image with only rev 182, and also zoom out to see if data farther south might be of interest. Generate your new map by typing:

IDL> albatross, loc=[51,330], /no_mo, /map, rev=182, size=35
  • rev limits the footprints to a single rev (orbit).
  • size scales the map to the input number in degrees (approx. 35 degrees)
Finally, you decide to center the image on a specific footprint right next to Lyot Crater. Move the mouse next to the crater, and click. You now have 3 seconds to move the mouse back to your Terminal to type the command below. Read the DAS number off of the plot and/or Info Box.

IDL> albatross, DAS=8119343, /no_mo, /map, rev=182, back='MDIM'
  • DAS centers on the location of the footprint taken nearest to the time.
  • back selects the background image. Valid choices are 'MOLA', 'MDIM', 'TES', 'GEO', and 'NONE' (case sensitive)
At this point you should be able to use the Albatross Software to interactively browse through the Mariner Mars 1971 Dataset. Once familiar with the software, read the Tips and Tricks section for advanced usage.

Albatross Data Structure

This section of the tutorial describes how to use the data structure returned by Albatross containing the footprints and ancillary information about each footprint. Run the following command:

IDL> albatross, loc=[51,330], rev=182, wavelen=w, reflectance=r
  • w contains the wavelength vector used as the X-AXIS in the plots.
  • r is an IDL structure, that contains the all of the footprints in the image. The number of footprints (265) is printed in the IDL session each time you run albatross.
If you type "IDL> help, r, /st" You will see that for each of the footprints, you get a spectrum vector of length 317 (r.reflectance), the Earth time the footprint was taken (r.sample_year, r.sample_doy, etc), the DAS (r.DAS), the REV (r.REV), etc... There are a total of 51 elements to the structure (51 pieces of information about each footprint).

Moving the mouse around the Albatross display, you see that footprint #86 is near Lyot Crater. To plot its spectra manually and display some information about it, type this: 
IDL> WINDOW, 0
IDL> plot, w, r[86].reflectance, psym=6, yr=[0.00,0.05]
IDL> print, r[86].DAS, r[86].mu, r[86].mu0
    8119348     0.957319     0.229030
  • You must type WINDOW, 0 if you move the mouse over the Albatross display, otherwise you will overplot the map.
This reflectance structure was generated by a call to Albatross that did not use the no_motion or mapping_only keywords. To get rid of spectra taken while in motion, type: 
IDL> good = where( r.motion_flag eq 0 )
IDL> r = r[ good ]
If you are interested in the 3050 Angstrom (3.05 nm) wavelength:
IDL> print, w[213]
    3049.00  ; closest measurement was taken at 3049 Angstroms.
To plot the 3050 wavelength of every footprint:
IDL> plot, r[*].reflectance[213]
To plot the 3050 wavelenths of every footprint as a function of latitude: 
IDL> plot, r[*].latitude_F2, r[*].reflectance[213], psym=6
Finally, the following code snippet does this:
  • Translates the longitudes from Mariner Mars 360W to the IDL 180E standard
  • Defines a map centered on the footprints
  • Plots each footprint at 3050 Angstroms, with color representing reflectance
  • Click here to see the image 
IDL> albatross, loc=[51,330], rev=182, wavelen=w, ref=r
IDL> window, 0
IDL> lats = r.latitude_f2
     ; translate from MM71 360W to IDL 180E
IDL> lons = lonxlate( r.longitude_f2, /from_360w, /to_180e )
IDL> map_set, mean(lats), mean(lons), /ortho, $
     LIMIT=[ min(lats), min(lons), max(lats), max(lons) ]
IDL> loadct, 39
IDL> plots, lons, lats, $
            color=BYTSCL( r.reflectance[213] ), $ ; scale to 255
            /data, psym=4, thick=3
IDL> map_grid, glinestyle=0, /LABEL

Albatross Data Array

This section of the tutorial describes how to use the data array returned by Albatross containing the footprints and ancillary information about each footprint. Run the following command:

IDL> albatross, loc=[51,330], rev=182, wavelen=w, array=a
  • w contains the wavelength vector used as the X-AXIS in the plots.
  • a is an 2D array, FLTARR( 366, N_FOOTPRINTS ) that contains all of the footprints in the image. The number of footprints (265 in this case) is printed in the IDL session each time you run albatross.
  • indices 0 to 316 is the reflectance
  • index 317 is the DAS
  • index 318 is rev (orbit number)
  • etc...
  • See the ALBATROSS_STRUCT2ARRAY procedure inside the albatross.pro file for the complete contents of the array.
Moving the mouse around the Albatross display, you see that footprint #86 is near Lyot Crater. To plot its spectra manually and display some information about it, type this: 
IDL> WINDOW, 0
IDL> plot, w, a[0:316,86], psym=6, yr=[0.00,0.05]
IDL> DAS = LONG( a[ 317, 86 ] )
IDL> mu = a[ 319, 86 ]
IDL> mu0 = a[ 320, 86 ]
IDL> print, DAS, mu, mu0
    8119348     0.957319     0.229030
  • You must type WINDOW, 0 if you move the mouse over the Albatross display, otherwise you will overplot the map. You should Pause the program (the p key) before you issue IDL commands outside of Albatross
This reflectance array was generated by a call to Albatross that did not use the no_motion or mapping_only keywords. To get rid of spectra taken while in motion, type: 
IDL> good = where( a[ 333, * ] EQ 0 )
IDL> a = a[ *, good ]
If you are interested in the 3050 Angstrom (3.05 nm) wavelength:
IDL> print, w[213]
    3049.00  ; closest measurement was taken at 3049 Angstroms.
To plot the 3050 wavelength of every footprint:
IDL> data3050 = a[ 213, * ]
IDL> plot, data3050
To plot the 3050 wavelenths of every footprint as a function of latitude: 
IDL> lats = a[ 339, * ]
IDL> data3050 = a[ 213, * ]
IDL> plot, lats, data3050, psym=6
Finally, the following code snippet does this:
  • Translates the longitudes from Mariner Mars 360W to the IDL 180E standard
  • Defines a map centered on the footprints
  • Plots each footprint at 3050 Angstroms, with color representing reflectance
  • Click here to see the image 
IDL> albatross, loc=[51,330], rev=182, wavelen=w, ref=r
IDL> window, 0
IDL> lats = a[ 339, * ]
     ; translate from MM71 360W to IDL 180E
IDL> lons = lonxlate( a[ 344, * ], /from_360w, /to_180e )
IDL> map_set, mean(lats), mean(lons), /ortho, $
     LIMIT=[ min(lats), min(lons), max(lats), max(lons) ]
IDL> loadct, 39
IDL> plots, lons, lats, $
         color=BYTSCL( a[ 213, * ] ), $ ; scale to 255
         /data, psym=4, thick=3
IDL> map_grid, glinestyle=0, /LABEL

Albatross Tips and Tricks

If you have color problems, type this as the first command after your start you IDL session: IDL> device, decomposed=0.

If you are going to issue IDL display commands (i.e. PLOT, TV) while Albatross is running, you should do the following:
  • Pause Albatross by pressing the p key. This will stop Albatross from making itself the current plot window. You can unPause Albatross by pressing p again.
  • IDL> WINDOW, 0 ;This will set up IDL so you do not plot into the Albatross mapping window.
You can control the plot parameters of Albatross via the IDL system variables (!x, !y). Each time you toggle from Ratio to Reflectance (via the r key), or make a new call to albatross they are reset.

Type this at the command line after you have issued you Albatross command: 
IDL> !p.charsize=1.3
IDL> !p.charthick=2
IDL> !y.range = [ 0, 0.03 ]
IDL> !y.ticks = 3
Here is a before and after image. This tip is especially useful when plotting in Ratio mode, because the y-axis is not fixed unless you do so manually.

Albatross loads its own colortables for the background image. This destroys the default colortable, so your external plotting commands will not work the way they normally do.

Visitor #[Error Creating Counter File -- Contact Web Administrator]since 2002-08-01